SM2YER Goran's Homepage

Bygger
DIY KODLÅS
Med en Aduino UNO

INDEX

Inledning

Senast uppdaterat

Beskrivning

Programmering

Budget / Transport

Referenser / Länkar m.m.

'Disclaimer'

Inledning
Bygger ett enkelt elektroniskt kodlås. Det ska användas till pannrum & till garaget för att slippa hålla reda på nycklar och upplåsning när t.ex. sotaren ska in.

Har valt just denna lösning, främst för att jag hittade en i princip helt komplett & tydlig beskrivning som borde passa perfekt för mina behov.

3D-Modell på utomhus-enhet.

Senast uppdaterat
2022.08.03 Funderar på den praktiska användningen av kodlåset, bl.a. måste det ju fungera även vid tillfälliga / kortare strömavbrott. (Vid långa avbrott kan man använda en vanlig nyckel) - Så där måste finnas någon form av batteri backup med underhålls-laddning.

12V - 4,5Ah batteri / Laddregulator modul

Arduino UNO kortet kan strömförsörjas direkt på DC ingången med 12VDC (6-20V), spolen i magnetlåset är också gjort för 12VDC - Sedan behövs där lite säkringar och kanske någon spärrdiod.

Utomhusdelarna, tangentbord & display monteras i en aluminiumbox som förbinds med innomhusdelarna med två kablar, en 8ledare och en 4ledare via RJ45 och RJ11 modular kontakter. Konstaterar att där inte behövs något sabotageskydd på utomhusdelen då där inte finns något att sabotera (Inget som kan manipuleras för att kringå koden).

RJ45 'Breakout board' / Modular PCB kontakt

Kommer att använda 'Breakout boards' för att nyttja standardkablar med RJ45 (8/8) och RJ11 (6/6) kontakter för att koppa mellan inom/utomhusdelarna. Då tangentbordet ska kopplas rakt på pin2--pin10, alla åtta ledare i följd kan RJ45 kontakten med 'breakout bord' sättas direkt i UNO utgångarna, det samma gäller till tangentbordet. Använder sedan en std. cat5e data kabel mellan.

2022.08.02 Hemma men Covid i några dagar till! - Har lite tråkigt, provar att ladda upp .ino koden till min Arduino UNO, och det fungerar! - Ritar en 3D-modell på utomhus delen med 'SketchUP', men tangentbort & display.

Kodlås på gång...

2022.08.01 Har påbörjat 'Vinter-Projekt-1', det blir ett enkelt kodlås, basserat på gammal återvunnen 'Arduino UNO' (v1) clone (Ej original) - Börjar som vanligt att experimentera med det material jag har hemma. I orginal koden använder man en 2x16 i2c display, jag har 4x20 displayer hemma o.s.v.

Planerar att använda följande material:

4x4 Tangentbord / 4x20 i2c Display

Arduino UNO / Relämodul

Innomhus kapsling / Utomhus kapsling

Magnetlås / knapp för UT-passage

Sammanställning av material & kostnader ligger under Budget / Transport

Beskrivning / Inkoppling
Börjar med att koppla in LCD-display och tangentbord enl. skiss nedan. kopplar LCD på 'AUX' utgången för att få alla fyra (SCL,SDA,VCC,GND) i en följd för att kunna använda RJ11 'Breakout board' och Modular (6/6) PCB kontakt. Tangentbordet sitter redan i rak följd på digital ingångarna 2--9, det gör att jag kan använda RJ45 'Breakout board' och Modular (8/8) PCB kontakt direkt.

Inkoppling av LCD & Keypad

Att koppla in relämodulen och 'UT-Knappen' är också ganska enkelt. (Se skiss nedan)

Inkoppling av Relä/Lås & UT-Knapp

Beskrivning / programkod
Ursprungskoden är väldigt bra, den är skriven av (Alias) 'SurtrTech' och ligger på 'Arduino Project HUB'[R1] - I koden ligger mycket förklarande text, det gör den lätt att förändra efter egna behov. Valde denna främst p.g.a. följande funktioner:

LED displayen visar vad som händer

Passer-koden kan vid behov ändras direkt från systemets tangentbord

Passer-koden lagras permanent i eeprom

Valbar längd på passer-koden

Har gjort lite ändringar i koden:
1. Rad 30--31, ändrat passerkodens längd från 4 till 6 siffror, kodexempel:


// char code[]= {'6','6','0','1'};       //The default code
char code[]= {'0','0','0','0','0','0'};  //Changed code

2. Lagt till lite förklarade text för att vägleda användaren, kodexempel:


lcd.print("Press * to start");          //What's written on the LCD when
lcd.setCursor(0,4);                     //returning to standby waiting
lcd.print("(c)2022 G.Larsson");         //for '*' to be pressed

Använder samma kodsnutt varje gång låset går tillbaka till startläget (Standby) på rad 49--51, 84--86, 92--94 och 106--108

3. Rad 98--101 Har lagt till kod som talar om att dörren är öppen även när man trycker på passage-UT knappen, använder samma kod på rad 236--239, kodexempel:


lcd.clear();
lcd.print("Welcome");                   //What's written on the
lcd.setCursor(0,2);                     //LCD when door is open
lcd.print("Door now open!");            //goe's on these lines

Notera! Glöm inte att 'avkommentera' rad 56--58 efter att koden laddats upp och passerkoden har ändrats. Ladda sedan upp den ändrade koden igen. (Detta är för att 'default' passerkoden inte finns i eEprom från början, den skrivs in när man ändrar första gången, sedan läses den lagrade passerkoden först efter att man 'avkommenterar' rad 56--58)

Min .ino programkod, bara att klippa & klistra!

#include <Keypad.h>
#include <EEPROM.h>
#include <LiquidCrystal_I2C.h>

#define Relay 11                //Controls the Relay
#define O_Button 10             //Push Button

#define I2C_ADDR 0x27           //I2C adress, you should use the code to scan the adress first (0x27) here
#define BACKLIGHT_PIN 3         // Declaring LCD Pins
#define En_pin 2
#define Rw_pin 1
#define Rs_pin 0
#define D4_pin 4
#define D5_pin 5
#define D6_pin 6
#define D7_pin 7

const byte numRows= 4;          //number of rows on the keypad
const byte numCols= 4;          //number of columns on the keypad

char keymap[numRows][numCols]= 
{
{'1', '2', '3', 'A'}, 
{'4', '5', '6', 'B'}, 
{'7', '8', '9', 'C'},
{'*', '0', '#', 'D'}
};

char keypressed;                 //Where the keys are stored it changes very often
char code[]= {'0','0','0','0','0','0'};  //The default code, you can change it or make it a 'n' digits one

char code_buff1[sizeof(code)];  //Where the new key is stored
char code_buff2[sizeof(code)];  //Where the new key is stored again so it's compared to the previous one

short a=0,i=0,s=0,j=0;          //Variables used later

byte rowPins[numRows] = {9,8,7,6}; //Rows 0 to 3 //if you modify your pins you should modify this too
byte colPins[numCols] = {5,4,3,2}; //Columns 0 to 3

LiquidCrystal_I2C lcd(I2C_ADDR,En_pin,Rw_pin,Rs_pin,D4_pin,D5_pin,D6_pin,D7_pin);
Keypad myKeypad= Keypad(makeKeymap(keymap), rowPins, colPins, numRows, numCols);

void setup()
         {
          lcd.begin (20,4);
          lcd.setBacklightPin(BACKLIGHT_PIN,POSITIVE);
          lcd.setBacklight(HIGH); //Lighting backlight
          lcd.home ();
          lcd.print("Press * to start");       //What's written on the LCD when
          lcd.setCursor(0,4);                  //returning to standby waiting
          lcd.print("(c)2022 G.Larsson");      //for '*' to be pressed 
          
          pinMode(Relay,OUTPUT);
          pinMode(O_Button,INPUT);            
          for(i=0 ; i<sizeof(code);i++){       //When you upload the code the first time keep it commented
          EEPROM.get(i, code[i]);              //Upload the code and change it to store it in the EEPROM
          digitalWrite(Relay,HIGH);            //Added to force door to close @ startuo
          }                                    //Then uncomment this for loop and reupload the code (It's done only once)

}

void loop()
{

keypressed = myKeypad.getKey();               //Constantly waiting for a key to be pressed
    if(keypressed == '*'){                      // * to open the lock
            lcd.clear();
            lcd.setCursor(0,0);
            lcd.print("Enter code");            //Message to show
            lcd.setCursor(0,4);
            lcd.print("A = Enter");
            GetCode();                          //Getting code function
                  if(a==sizeof(code))           //The GetCode function assign a value to a (it's correct when it has the size of the code array)
                  OpenDoor();                   //Open lock function if code is correct
                  else{
                  lcd.clear();               
                  lcd.print("Wrong code!");     //Message to print when the code is wrong
                  lcd.setCursor(0,2);
                  lcd.print("Please trye again!");      //What's written on the LCD you can change
                  }
            delay(2000);
            lcd.clear();
            lcd.print("Press * to start");       //What's written on the LCD when
            lcd.setCursor(0,4);                  //returning to standby waiting
            lcd.print("(c)2022 G.Larsson");      //for '*' to be pressed
        }

if(keypressed == '#'){                     //To change the code it calls the changecode function
      ChangeCode();
      lcd.clear();
      lcd.print("Press * to start");       //What's written on the LCD when
      lcd.setCursor(0,4);                  //returning to standby waiting
      lcd.print("(c)2022 G.Larsson");      //for '*' to be pressed 
     }

if(digitalRead(O_Button)==HIGH){           //Opening by the push button
       lcd.clear();
       lcd.print("Welcome");                    //What's written on the
       lcd.setCursor(0,2);                      //LCD when door is open
       lcd.print("Door now open!");             //goe's on these lines
       digitalWrite(Relay,LOW);
       delay(3000);                             //Opens for 3s you can change
       digitalWrite(Relay,HIGH);
       lcd.clear();
       lcd.print("Press * to start");       //What's written on the LCD when
       lcd.setCursor(0,4);                  //returning to standby waiting
       lcd.print("(c)2022 G.Larsson");      //for '*' to be pressed 
     }
         
}

void GetCode(){                  //Getting code sequence
       i=0;                      //All variables set to 0
       a=0;
       j=0; 
                                     
     while(keypressed != 'A'){                                     //The user press A to confirm the code otherwise he can keep typing
           keypressed = myKeypad.getKey();                         
             if(keypressed != NO_KEY && keypressed != 'A' ){       //If the char typed isn't A and neither "nothing"
              lcd.setCursor(j,1);                                  //This to write "*" on the LCD whenever a key is pressed it's position is controlled by j
              lcd.print("*");
              j++;
            if(keypressed == code[i]&& i<sizeof(code)){            //if the char typed is correct a and i increments to verify the next caracter
                 a++;                                              //Now I think maybe I should have use only a or i ... too lazy to test it -_-'
                 i++;
                 }
            else
                a--;                                               //if the character typed is wrong a decrements and cannot equal the size of code []
            }
            }
    keypressed = NO_KEY;

}

void ChangeCode(){                      //Change code sequence
      lcd.clear();
      lcd.print("Changing code");
      delay(1000);
      lcd.clear();
      lcd.print("Enter old code");
      GetCode();                      //verify the old code first so you can change it
      
            if(a==sizeof(code)){      //again verifying the a value
            lcd.clear();
            lcd.print("Changing code");
            GetNewCode1();            //Get the new code
            GetNewCode2();            //Get the new code again to confirm it
            s=0;
              for(i=0 ; i<sizeof(code) ; i++){    //Compare codes in array 1 and array 2 from two previous functions
              if(code_buff1[i]==code_buff2[i])
              s++;                                //again this how we verifiy, increment s whenever codes are matching
              }
                  if(s==sizeof(code)){            //Correct is always the size of the array
                  
                   for(i=0 ; i<sizeof(code) ; i++){
                  code[i]=code_buff2[i];          //the code array now receives the new code
                  EEPROM.put(i, code[i]);         //And stores it in the EEPROM
                  
                  }
                  lcd.clear();
                  lcd.print("Code Changed");
                  delay(2000);
                  }
                  else{                         //In case the new codes aren't matching
                  lcd.clear();
                  lcd.print("Codes are not");
                  lcd.setCursor(0,1);
                  lcd.print("matching !!");
                  delay(2000);
                  }
            
          }
          
          else{                     //In case the old code is wrong you can't change it
          lcd.clear();
          lcd.print("Wrong code!");
          lcd.setCursor(0,2);
          lcd.print("Please trye again!");      //What's written on the LCD you can change
          delay(2000);
          }
}

void GetNewCode1(){                      
  i=0;
  j=0;
  lcd.clear();
  lcd.print("Enter new code");   //tell the user to enter the new code and press A
  lcd.setCursor(0,1);
  lcd.print("and press A");
  delay(2000);
  lcd.clear();
  lcd.setCursor(0,1);
  lcd.print("and press A");     //Press A keep showing while the top row print ***
             
         while(keypressed != 'A'){            //A to confirm and quits the loop
             keypressed = myKeypad.getKey();
               if(keypressed != NO_KEY && keypressed != 'A' ){
                lcd.setCursor(j,0);
                lcd.print("*");               //On the new code you can show * as I did or change it to keypressed to show the keys
                code_buff1[i]=keypressed;     //Store caracters in the array
                i++;
                j++;                    
                }
                }
keypressed = NO_KEY;
}

void GetNewCode2(){                         //This is exactly like the GetNewCode1 function but this time the code is stored in another array
  i=0;
  j=0;
  
  lcd.clear();
  lcd.print("Confirm code");
  lcd.setCursor(0,1);
  lcd.print("and press A");
  delay(3000);
  lcd.clear();
  lcd.setCursor(0,1);
  lcd.print("and press A");

while(keypressed != 'A'){
             keypressed = myKeypad.getKey();
               if(keypressed != NO_KEY && keypressed != 'A' ){
                lcd.setCursor(j,0);
                lcd.print("*");
                code_buff2[i]=keypressed;
                i++;
                j++;                    
                }
                }
keypressed = NO_KEY;
}

void OpenDoor(){                   //Lock opening function open for 3s
  lcd.clear();
  lcd.print("Welcome");                    //What's written on the
  lcd.setCursor(0,2);                      //LCD when door is open
  lcd.print("Door now open!");             //goe's on these lines
  digitalWrite(Relay,LOW);
  delay(3000);
  digitalWrite(Relay,HIGH);
}

Tekniska data 'DIY Kodlås'
=====================================================================
Typ ............................... 
=====================================================================

Några noteringar Plus :-)

Lärorikt & Roligt

Billigare än komersiella lösningar

Några noteringar Minus :-(

Kan vara lite 'överkurs'

Budget / Transport

Kostnader t.o.m. 2022.08.02

Länkar / Leverantörer / Referenser
Honors to the brains behind - 'Äras den som äras bör' - som talesättet säger. Som vanligt så är det inte jag som kommit på allt detta. Här hittar ni länkar till referenser och leverantörer.

Leverantörer:
[L1] Electrokit.se
[L2] BILTEMA.se
[L3] Conrad.se
[L4] eBay.com

Länkar / Referenser:
[R1] Ursprunglig programkod @ Arduino Project HUB
[R2] modifierad programkod @ surtrtech.com

'Disclaimer'
The information given on this page is given on an 'As Is' basis and aimed for NON COMMERCIAL use only. The author can not be held responsible for any use of the information. Any registered product / trademark or company name on the page is the property of their respective owners.

Notera!
Det är helt personliga reflektioner och upplevelser vi skriver om på den här sidan, dessa är inte några 'Expert' kommentarer / utlåtanden. Vi rekommenderar INTE att någon ska göra dom ändringar / Modifieringar som vi gjort och som beskrivs på denna sida, då dessa HELT SÄKERT gör att alla garantier som leverantören utställt OMEDELBART upphör.

Våra tester och slutsatser kan INTE, och ska INTE tas för intäkt att samma eller motsvarande resultat eller upplevelse kan erhållas eller efterliknas någon annanstans eller av någon annan.

Go Back!